Foro de programación ABAP

REPORT zalv_dinamico.

TABLES : sscrfields.
*
*-------------------------------------------------------------------------------------------------------------------*
* DECLARACION DE TYPE-POOLS
*-------------------------------------------------------------------------------------------------------------------*
*
TYPE-POOLS : abap.                                                                                                  " ABAP Language Type-Pool
TYPE-POOLS : slis.                                                                                                  " Tipos globales creacion de ALV
*-------------------------------------------------------------------------------------------------------------------*
* DECLARACION DE INCLUDES
*-------------------------------------------------------------------------------------------------------------------*
INCLUDE : <icon>.                                                                                                   " Definicion de Iconos - ASCII-Codes
INCLUDE : <cl_alv_control>.                                                                                         " Definicion de Estilos de Celdas ALV

*
*-------------------------------------------------------------------------------------------------------------------*
* DECLARACION DE TYPE-POOLS
*-------------------------------------------------------------------------------------------------------------------*
TYPE-POOLS : vrm.
TYPE-POOLS : sscr.
TYPE-POOLS : rsds.
*-------------------------------------------------------------------------------------------------------------------*
* DECLARACION DE INCLUDES
*-------------------------------------------------------------------------------------------------------------------*
*-------------------------------------------------------------------------------------------------------------------*
* CLASES ABAP
*-------------------------------------------------------------------------------------------------------------------*
CLASS cl_abap_char_utilities DEFINITION LOAD.
*-------------------------------------------------------------------------------------------------------------------*
* CONSTANTES : DEFINICION PARA SEPARADORES DE CAMPOS
*-------------------------------------------------------------------------------------------------------------------*

*
*VALORES DE VERADDERO/FALSO
CONSTANTS : co_falso               TYPE c LENGTH 001                       VALUE 'F'.                              " False
CONSTANTS : co_verdadero           TYPE c LENGTH 001                       VALUE 'T'.                              " Verdadero
*-------------------------------------------------------------------------------------------------------------------*
* DECLARACION DE DATOS GLOBALES
*-------------------------------------------------------------------------------------------------------------------*
*
DATA : gd_continuar               TYPE c LENGTH 01                        VALUE co_falso.
*
*VARIABLES PARA DYNPROS
DATA : ok_code                    TYPE sy-ucomm.
*
*-------------------------------------------------------------------------------------------------------------------*
* DECLARACION DE DATOS GLOBALES DINAMICOS :
*-------------------------------------------------------------------------------------------------------------------*
*
DATA : ref_line_type  TYPE REF TO cl_abap_structdescr.
DATA : ref_tabletype  TYPE REF TO cl_abap_tabledescr.
DATA : ref_wa         TYPE REF TO data.
*
DATA : ref_itab       TYPE REF TO data.
DATA : ref_out        TYPE REF TO cl_salv_table.
*
DATA : ref_functions  TYPE REF TO cl_salv_functions_list.
*
DATA : ref_header     TYPE REF TO cl_salv_form_layout_grid.
DATA : ref_label      TYPE REF TO cl_salv_form_label.
DATA : ref_tab        TYPE string.
*
DATA : ld_tabla       TYPE tabname.
*
FIELD-SYMBOLS : <fsym_itab> TYPE ANY TABLE.
FIELD-SYMBOLS : <fsym_field> TYPE ANY.

DATA : ls_functxt                           TYPE smp_dyntxt.
*
* DEFINICION DATOS LOCALES PARA TRATAMIENTO DINAMICO
DATA : lo_dynamic_struct                    TYPE REF TO cl_abap_structdescr.
DATA : lt_comp_tabla                        TYPE cl_abap_structdescr=>component_table.
DATA : lo_dref_comptbi                      TYPE REF TO data.
DATA : lo_dref_locstr                       TYPE REF TO data.
DATA : lo_dref_loctbi                       TYPE REF TO data.
*
*-------------------------------------------------------------------------------------------------------------------*
* DECLARACION DE TIPOS DE TABLAS - TABLAS INTERNAS :
*-------------------------------------------------------------------------------------------------------------------*
*
DATA : ld_selection_id                      TYPE rsdynsel-selid.                            " ID de selección para diferenciar entre varios conjuntos
*
DATA : ld_tabclass                          TYPE tabclass.                                  " Clase tabla
DATA : ld_tablename                         TYPE string.
DATA : ld_num_fields                        TYPE i.                                         " numero de campos
*
DATA : lt_expressions                       TYPE rsds_texpr.                                " Expresiones
DATA : lt_field_ranges                      TYPE rsds_trange.                               " Rangos
DATA : ls_field_ranges                      LIKE LINE OF lt_field_ranges.
*
DATA : lt_tables_ini                        TYPE STANDARD TABLE OF rsdstabs.                " Init: tablas
DATA : sl_tables_ini                        LIKE LINE OF lt_tables_ini.
*
DATA : lt_fields_ini                        TYPE STANDARD TABLE OF rsdsfields.              " Init: campos
DATA : sl_fields_ini                        LIKE LINE OF lt_fields_ini.
*
DATA : lt_where_cond                        TYPE rsds_twhere.                               " Datos para la tabla where
DATA : ls_where_clause                      LIKE LINE OF lt_where_cond.
*
DATA : lt_where_tab                         TYPE STANDARD TABLE OF rsds_where_tab.
DATA : ls_where_tab                         LIKE LINE OF lt_where_tab.
*
DATA : lt_tabfields_not_display             TYPE TABLE OF rsdsfields.
DATA : ls_tabfields_not_display             LIKE LINE OF lt_tabfields_not_display.
*
DATA : gd_titulo_externo                    TYPE c LENGTH 080.
*
*-------------------------------------------------------------------------------------------------------------------*
* DECLARACION DE FIELD-SYMBOLS
*-------------------------------------------------------------------------------------------------------------------*
*
* DEFINICION FIELD-SYMBOLS LOCALES PARA TRATAMIENTO DINAMICO
FIELD-SYMBOLS : <fs_valor_campo>            TYPE ANY.
*
FIELD-SYMBOLS : <fs_valor_struc>            TYPE ANY.
FIELD-SYMBOLS : <fs_comp_tabla>             LIKE LINE OF lt_comp_tabla.
*
FIELD-SYMBOLS : <fs_dynamic_tbi>            TYPE ANY TABLE.
FIELD-SYMBOLS : <fs_dynamic_str>            TYPE ANY.
*-------------------------------------------------------------------------------------------------------------------*
*
*-------------------------------------------------------------------------------------------------------------------*
*
PARAMETERS : pa_tab TYPE dd02l-tabname.

*-----------------------------------------------------------------------------------------------------------------*
* START-OF-SELECTION.
*-----------------------------------------------------------------------------------------------------------------*
START-OF-SELECTION.
*
  ld_tablename      = pa_tab.
*
  CLEAR : ld_tabclass.
  SELECT SINGLE tabclass INTO ld_tabclass
    FROM dd02l
      WHERE  tabname   EQ ld_tablename
      AND    as4local  EQ 'A'
      AND    tabclass  EQ 'TRANSP'.
*
  IF ( sy-subrc EQ 0 ) AND NOT ( ld_tabclass IS INITIAL ).
*
    PERFORM get_data_parametros_dynpro.
*
    PERFORM actualiza_titulo.
*
    CALL FUNCTION 'FREE_SELECTIONS_INIT'
      EXPORTING
        kind                     = 'T'
        expressions              = lt_expressions
      IMPORTING
        selection_id             = ld_selection_id
        field_ranges             = lt_field_ranges
      TABLES
        tables_tab               = lt_tables_ini
        fields_tab               = lt_fields_ini
        tabfields_not_display    = lt_tabfields_not_display
      EXCEPTIONS
        fields_incomplete        = 1
        fields_no_join           = 2
        field_not_found          = 3
        no_tables                = 4
        table_not_found          = 5
        expression_not_supported = 6
        incorrect_expression     = 7
        illegal_kind             = 8
        area_not_found           = 9
        inconsistent_area        = 10
        kind_f_no_fields_left    = 11
        kind_f_no_fields         = 12
        too_many_fields          = 13
        dup_field                = 14
        field_no_type            = 15
        field_ill_type           = 16
        dup_event_field          = 17
        node_not_in_ldb          = 18
        area_no_field            = 19
        OTHERS                   = 20.
    IF ( sy-subrc NE 0 ).

    ELSE.

    ENDIF.

*   MOSTRAR PANTALLA DE SELECCIÓN LIBRE
    CALL FUNCTION 'FREE_SELECTIONS_DIALOG'
      EXPORTING
        selection_id            = ld_selection_id
        title                   = sy-title
        frame_text              = 'Parametros de Seleccion'
        status                  = '1'
        as_window               = abap_false
        no_intervals            = abap_true
      IMPORTING
        where_clauses           = lt_where_cond
        expressions             = lt_expressions
        field_ranges            = lt_field_ranges
        number_of_active_fields = ld_num_fields
      TABLES
        fields_tab              = lt_fields_ini
      EXCEPTIONS
        internal_error          = 1
        no_action               = 2
        selid_not_found         = 3
        illegal_status          = 4
        OTHERS                  = 5.
    IF ( sy-subrc EQ 0 ).
      gd_continuar = co_verdadero.
    ENDIF.
  ELSE.
    gd_continuar = co_falso.
  ENDIF.
*
  IF ( gd_continuar EQ co_verdadero ).
*
    IF ( gd_continuar EQ co_verdadero ).
      PERFORM get_main_data.
*
      IF ( <fs_dynamic_tbi>[] IS INITIAL ).
        MESSAGE i899(v1) WITH 'Sin Datos' DISPLAY LIKE 'I'.
        gd_continuar = co_falso.
      ENDIF.
    ELSE.
      gd_continuar = co_falso.
    ENDIF.
  ENDIF.
*
  IF ( gd_continuar EQ co_falso ).
    LEAVE TO SCREEN 0.
  ENDIF.
*
*-----------------------------------------------------------------------------------------------------------------*
* END-OF-SELECTION
*-----------------------------------------------------------------------------------------------------------------*
END-OF-SELECTION.

  PERFORM show_data_alv USING ld_tablename.



*-----------------------------------------------------------------------------------------------------------------*
* INCLUDES DE RUTINAS FORM
*-----------------------------------------------------------------------------------------------------------------*
*
*-------------------------------------------------------------------------------------------------------------------*
* FORM : GET_MAIN_DATA
*-------------------------------------------------------------------------------------------------------------------*
FORM get_main_data.
*
  DATA : lt_field                 TYPE ddfields.
*
  DATA : ld_existe_ori            TYPE c LENGTH 001 VALUE co_falso.
  DATA : ld_varaux                TYPE string.
  DATA : lt_where_aux             TYPE STANDARD TABLE OF rsdswhere.
  DATA : ls_where_aux             LIKE LINE OF lt_where_aux.

  DATA : ld_cantregi              TYPE sy-tabix.
  DATA : lt_campos                TYPE STANDARD TABLE OF string.
  DATA : ld_campo                 TYPE string.
  DATA : type_descr               TYPE REF TO cl_abap_typedescr.
  DATA : struct_descr             TYPE REF TO cl_abap_structdescr.
  DATA : components               TYPE cl_abap_structdescr=>component_table.
  DATA : component                LIKE LINE OF components.
  DATA : error                    TYPE REF TO cx_root.
*
* DEFINICION DATOS LOCALES PARA TRATAMIENTO DINAMICO
  DATA : lo_dref_locstr           TYPE REF TO data.
  DATA : lo_dref_loctbi           TYPE REF TO data.
  DATA : ld_tabname               TYPE tabname.
*
  ld_tabname  = ld_tablename.
*
  FIELD-SYMBOLS : <fs_dfies>      TYPE dfies.
  FIELD-SYMBOLS : <fs_where>      TYPE rsdswhere.
*
* GENERACION DINAMICA DE LA ESTRUCTURA
  CREATE DATA lo_dref_loctbi TYPE STANDARD TABLE OF (ld_tabname) WITH NON-UNIQUE DEFAULT KEY.
  ASSIGN lo_dref_loctbi->* TO <fs_dynamic_tbi>.
*
  CREATE DATA lo_dref_locstr LIKE LINE OF <fs_dynamic_tbi>.
  ASSIGN lo_dref_locstr->* TO <fs_dynamic_str>.
*
  IF ( sy-subrc EQ 0 ).
    TRY.
*
        CALL METHOD zcl_mm_blueyonder=>get_fields_structure
          EXPORTING
            iv_name   = ld_tabname
          IMPORTING
            et_fields = lt_field[].

        LOOP AT lt_field ASSIGNING <fs_dfies>.
          IF ( <fs_dfies>-datatype EQ 'CLNT' ) OR ( <fs_dfies>-datatype EQ 'STRU' ).

          ELSE.
            CLEAR : ld_campo.
            ld_campo = <fs_dfies>-fieldname.
            APPEND ld_campo TO lt_campos.
          ENDIF.
        ENDLOOP.

        IF NOT ( lt_campos[] IS INITIAL ).
          IF ( LINES( lt_where_cond ) GT 0 ).
            LOOP AT lt_where_cond INTO ls_where_clause WHERE tablename EQ ld_tablename.
              APPEND LINES OF ls_where_clause-where_tab[] TO lt_where_aux[].
            ENDLOOP.

            SELECT *
              INTO CORRESPONDING FIELDS OF TABLE <fs_dynamic_tbi>[]
                FROM  (ld_tablename)
                  WHERE (lt_where_aux) ORDER BY PRIMARY KEY.
          ELSE.
            SELECT *
              INTO CORRESPONDING FIELDS OF TABLE <fs_dynamic_tbi>[]
                FROM (ld_tablename)
                  WHERE (lt_where_aux) ORDER BY PRIMARY KEY.
          ENDIF.
        ENDIF.
      CATCH cx_sy_move_cast_error INTO error.
        MESSAGE error TYPE 'I' DISPLAY LIKE 'E'.
        RETURN.
    ENDTRY.
*
  ENDIF.
*
ENDFORM.                                                                                                            "
*-------------------------------------------------------------------------------------------------------------------*
* FORM : GET_DATA_PARAMETROS_DYNPRO
*-------------------------------------------------------------------------------------------------------------------*
FORM get_data_parametros_dynpro.
*
  DATA : ld_tabname               TYPE tabname.
  DATA : lt_field                 TYPE ddfields.
*
  DATA : ld_ddtext                TYPE ddtext.
*
  FIELD-SYMBOLS : <fs_dfies>      TYPE dfies.
*
  CLEAR : lt_expressions[], lt_field_ranges[], lt_tables_ini[], lt_fields_ini[],
          lt_where_cond[], lt_where_tab[], lt_tabfields_not_display[].
*
  sl_tables_ini-prim_tab  = ld_tablename.
  APPEND sl_tables_ini TO lt_tables_ini.
*
  ld_tabname  = ld_tablename.
  CALL METHOD zcl_mm_blueyonder=>get_fields_structure
    EXPORTING
      iv_name   = ld_tabname
    IMPORTING
      et_fields = lt_field[].
*
  LOOP AT lt_field ASSIGNING <fs_dfies>.
    IF ( <fs_dfies>-keyflag  EQ abap_true ) AND ( <fs_dfies>-datatype NE 'CLNT'    ).
      CLEAR : sl_fields_ini.
      sl_fields_ini-tablename      = ld_tabname.
      sl_fields_ini-fieldname      = <fs_dfies>-fieldname.
      sl_fields_ini-type           = 'S'.
      sl_fields_ini-where_leng     = <fs_dfies>-leng.
      APPEND sl_fields_ini TO lt_fields_ini.
    ENDIF.
  ENDLOOP.
*
  IF ( gd_titulo_externo IS INITIAL ).
    CLEAR : ld_ddtext.
    SELECT SINGLE ddtext INTO ld_ddtext
      FROM  dd02t
        WHERE  tabname     EQ ld_tabname
        AND    ddlanguage  EQ sy-langu
        AND    as4local    EQ 'A'.
    IF ( sy-subrc EQ 0 ) AND ( ld_ddtext IS INITIAL ).
      gd_titulo_externo = ld_ddtext.
    ENDIF.
  ENDIF.
*
ENDFORM.                                                                                                            "
*-------------------------------------------------------------------------------------------------------------------*
* FORM : ACTUALIZA_TITULO
*-------------------------------------------------------------------------------------------------------------------*
FORM actualiza_titulo.
*
  DATA : ld_titu_reporte                    TYPE string.
  DATA : ld_nomb_reporte                    TYPE string.
  DATA : ld_param_01                        TYPE c LENGTH 030 .
  DATA : ld_param_02                        TYPE c LENGTH 030 .
  DATA : ld_param_03                        TYPE c LENGTH 030 .
  DATA : ld_param_04                        TYPE c LENGTH 030 .
*
  DATA : ld_msg_aux_01                      TYPE string.
  DATA : ld_msg_aux_02                      TYPE string.
  DATA : ld_msg_aux_03                      TYPE string.
*
  DATA : ld_tabname               TYPE tabname.
  DATA : ld_ddtext                TYPE ddtext.

  SET TITLEBAR  'T_01'.
*
  ld_titu_reporte = 'T_01'.
  ld_nomb_reporte = 'ZALV_DINAMICO'.
*
  ld_tabname  = ld_tablename.
*
  CLEAR : ld_ddtext.
  SELECT SINGLE ddtext INTO ld_ddtext
    FROM  dd02t
      WHERE  tabname     EQ ld_tabname
      AND    ddlanguage  EQ sy-langu
      AND    as4local    EQ 'A'.
*
  ld_param_01 = 'Tabla :'.
  CONCATENATE ld_tabname '-' '(' INTO ld_param_02  SEPARATED BY space.
  CONCATENATE  ld_ddtext ')' INTO ld_param_03.
  SET TITLEBAR ld_titu_reporte OF PROGRAM ld_nomb_reporte WITH ld_param_01 ld_param_02 ld_param_03 ld_param_04.
*
ENDFORM.                                                                                                           "
*-------------------------------------------------------------------------------------------------------------------*
* FORM : SHOW_DATA_ALV
*-------------------------------------------------------------------------------------------------------------------*
FORM show_data_alv  USING    p_ld_tablename.
*
  CLEAR : ld_tabla.
  ld_tabla = p_ld_tablename.
*
* CREAR TIPO LINEA Y TIPO TABLA CON : RTTC
  ref_line_type ?= cl_abap_typedescr=>describe_by_name( ld_tabla ).
  ref_tabletype = cl_abap_tabledescr=>create( p_line_type = ref_line_type ).
*
* OBJETO CREADO CON : RTTC.
  CREATE DATA ref_itab TYPE HANDLE ref_tabletype.
  CREATE DATA ref_wa TYPE HANDLE ref_line_type.
*
* ASIGNAR TIPO
  ASSIGN ref_itab->* TO <fsym_itab>.
*
* LLAMAR ALV.
  TRY.
      CALL METHOD cl_salv_table=>factory
        IMPORTING
          r_salv_table = ref_out
        CHANGING
          t_table      = <fs_dynamic_tbi>.
    CATCH cx_salv_msg .
  ENDTRY.
*
  ref_functions = ref_out->get_functions( ).
  ref_functions->set_all( if_salv_c_bool_sap=>true ).
*
  CREATE OBJECT ref_header.
  CREATE OBJECT ref_label.
*
  ref_label = ref_header->create_label( row = 1 column = 1 ).
  CONCATENATE 'Contenido :' ld_tabla INTO ref_tab SEPARATED BY space.
  ref_label->set_text( ref_tab ).
  ref_out->set_top_of_list( ref_header ).
  ref_out->set_top_of_list_print( ref_header ).
  ref_out->display( ).
*
* LIMPIAR FIELD SYMBOLS
  UNASSIGN : <fsym_itab>.
  FREE ref_out.
*
ENDFORM.                                                                                                           "

GET_TABLE_SIZE_ADA
GET_TABLE_SIZE_MSS
GET_TABLE_SIZE_ORA
GET_TABLE_SIZE_DB2
GET_TABLE_SIZE_DB4
GET_TABLE_SIZE_DB6
GET_TABLE_SIZE_INF
GET_TABLE_SIZE_ALL
GET_TABLE_SIZE_ALL

Aquí les dejo un report  que permite seleccionar archivos desde el servidor de aplicación o presentación.
Espero les sea de utilidad.

REPORT Z_GET_ARCHIVO_SRV_LOCAL.
*-----------------------------------------------------------------------------------------------------------------------------------------*
DATA : ld_rc(10)              TYPE c.
DATA : ld_filename            TYPE string.
*-----------------------------------------------------------------------------------------------------------------------------------------*
DATA : ld_location_flag       TYPE  dxlocation.     " Indicador: Servidor de aplicación o presentación : A = Server SAP   // P = PC Local
DATA : ld_server              TYPE  msname2.        " Nombre del servidor de aplicación (SOLO PARA SERVER SAP)
DATA : ld_path                TYPE  dxlpath.        " Vía acceso más larga
DATA : ld_filemask            TYPE  dxfilemask.     " Máscara p.nom.fichero
DATA : ld_fileoperation       TYPE  dxfileoper.     " Tipo de Operacion con el Archivo : R = Leer  // W = Escribir
*-----------------------------------------------------------------------------------------------------------------------------------------*
*

PARAMETERS : p_srv            RADIOBUTTON GROUP gr1.
PARAMETERS : p_loc            RADIOBUTTON GROUP gr1.
*
*-----------------------------------------------------------------------------------------------------------------------------------------*


*
*--->> PARA SELECIONAR ARCHIVOS DESDE EL SERVER SAP
IF ( p_srv EQ 'X' ).
  ld_location_flag  = 'A'.
  ld_path           = '/usr/sap/tmp'.
  ld_filemask       = '*.*'.
  ld_fileoperation  = 'R'.
ENDIF.

*
*--->> PARA SELECIONAR ARCHIVOS DESDE LOCAL PC
IF ( p_loc EQ 'X' ).
  ld_location_flag  = 'P'.
  ld_path           = 'C:\TEMP\'.
  ld_filemask       = '*.*'.
  ld_fileoperation  = 'R'.
ENDIF.


*-----------------------------------------------------------------------------------------------------------------------------------------*
START-OF-SELECTION.
*
  PERFORM get_filename_pc_sev USING     ld_location_flag
                                        ld_path
                                        ld_filemask
                                        ld_fileoperation
                              CHANGING  ld_rc
                                        ld_filename.
*
  WRITE : / 'RC       : ', ld_rc.
  WRITE : / 'ARCHIVO  : ', ld_filename.
*
END-OF-SELECTION.
*-----------------------------------------------------------------------------------------------------------------------------------------*
*
*
*-----------------------------------------------------------------------------------------------------------------------------------------*
*  FORM : GET_FILENAME_PC_SEV
*-----------------------------------------------------------------------------------------------------------------------------------------*
*       Leer Nombre de un archivo desde el servidor SAP o LOCAL
*-----------------------------------------------------------------------------------------------------------------------------------------*
*      -->P_LD_LOCATION_FLAG      Indicador: Servidor de aplicación o presentación : A = Server SAP   // P = PC Local
*      -->P_LD_PATH               Vía acceso más larga
*      -->P_LD_FILEMASK           Máscara p.nom.fichero
*      -->P_LD_FILEOPERATION      Tipo de Operacion con el Archivo : R = Leer  // W = Escribir
*      <--P_LD_RC
*      <--P_LD_FILENAME
*-----------------------------------------------------------------------------------------------------------------------------------------*
FORM get_filename_pc_sev  USING    p_location_flag
                                   p_path
                                   p_filemask
                                   p_fileoperation
                          CHANGING p_rc
                                   p_filename.

*
* ----->>> DECLARACION DE VARIABLES
  DATA  : ld_o_location_flag      TYPE dxlocation.                      " Indicador: Servidor de aplicación o presentación
  DATA  : ld_o_server             TYPE msname2.                         " Nombre del servidor de aplicación
  DATA  : ld_o_path               TYPE dxlpath.                         " Vía acceso más larga
  DATA  : ld_abend_flag           TYPE dxxabend.                        " Indicador: Cancelación del proceso
  DATA  : ld_filesys              TYPE filesys_d.                       " Grupo de sintaxis para nombres de ficheros y vías de acceso
  DATA  : lw_rfcsi_export         TYPE rfcsi.                           " RFC Versión log
  DATA  : ld_server               TYPE msname2.                         " Nombre del servidor de aplicación
*
  DATA  : ld_path                 TYPE string.                          " Path para Archivos PC
  DATA  : ld_mascara              TYPE string.                          " Marcara para Archivos PC
  DATA  : lt_file_table           TYPE STANDARD TABLE OF file_table.    " Tabla Interna para guardar archivo seleccionado desde el PC
  DATA  : lw_file_table           LIKE LINE OF lt_file_table.           "
  DATA  : ld_subrc                TYPE i.                               " Para retorno de la funcion de seleccion de archivos del PC

  IF ( p_location_flag EQ 'A' ).
  ENDIF.


  CASE p_location_flag.
*
*   ----->>> EJECUTAR FUNCION PARA SELECCIONAR ARCHIVO DESDE SERVIDOR DE APLICACION : 'SAP'
    WHEN 'A'.
*
*     ----->>> RECUPERAR EL SISTEMA OPERATIVO DEL LOS SERVIDORES DE APLICACIONES : APLICACION Y PRESENTACION
      SELECT SINGLE filesys
        FROM opsystem INTO ld_filesys
          WHERE opsys EQ sy-opsys.
*
*     ----->>> RECUPERAR DESTINO LOGICO DEL SISTEMA
      CALL FUNCTION 'RFC_SYSTEM_INFO'
        IMPORTING
          rfcsi_export = lw_rfcsi_export.
*
*     ----->>> RECUPERAR NOMBER DEL SERVER SAP
      ld_server = lw_rfcsi_export-rfcdest.
*
*     ----->>> SI RUTA ES VACIO : UTILIZAR '?'
      IF ( ld_server IS INITIAL ).
        ld_server = '?'.
      ENDIF.
*
*     ----->>> SI MASCARA PARA SELECCION DE TIPO DE ARCHIVOS ES VACIA : UTILIZAR '*.*'
      IF ( p_filemask IS INITIAL ).
        p_filemask = '*.*'.
      ENDIF.
*
*     ----->>> LLAMADA A LA FUNCION DE SELECCION DE ARCHIVOS EN SERVER SAP
      CALL FUNCTION 'F4_DXFILENAME_TOPRECURSION'
        EXPORTING
          i_location_flag = p_location_flag             " Indicador: Servidor de aplicación o presentación : A = Server SAP   // P = PC Local
          i_server        = ld_server                   " Nombre del servidor de aplicación
          i_path          = p_path                      " Vía acceso más larga
          filemask        = p_filemask                  " Máscara p.nom.fichero
          fileoperation   = p_fileoperation             " Tipo de Operacion con el Archivo : R = Leer  // W = Escribir
        IMPORTING
          o_location_flag = ld_o_location_flag
          o_server        = ld_o_server
          o_path          = ld_o_path
          abend_flag      = ld_abend_flag
        EXCEPTIONS
          rfc_error       = 1
          error_with_gui  = 2
          OTHERS          = 3.
*
*   ----->>> EJECUTAR FUNCION PARA SELECCIONAR ARCHIVO DESDE SERVIDOR DE PRESENTACION : 'LOCAL PC'
    WHEN 'P'.
*
      IF ( p_path IS INITIAL ).
        ld_path = 'C:\'.
      ELSE.
        ld_path     = p_path.
      ENDIF.
*
      IF ( p_filemask IS INITIAL ).
        ld_mascara  = '*.*'.
      ELSE.
        ld_mascara  = p_filemask.
      ENDIF.
*
*     ----->>> LLAMADA AL METODO DE SELECCION DE ARCHIVOS DESDE PC
      CALL METHOD cl_gui_frontend_services=>file_open_dialog
        EXPORTING
          window_title            = 'Seleccione Archivo'
          default_extension       = ld_mascara
          initial_directory       = ld_path
        CHANGING
          file_table              = lt_file_table
          rc                      = ld_subrc
        EXCEPTIONS
          file_open_dialog_failed = 1
          cntl_error              = 2
          error_no_gui            = 3
          not_supported_by_gui    = 4
          OTHERS                  = 5.
*
*   ----->>> VALIDA LA EJECUCION Y HOMOLOGA VALORES DE RETORNO DE LA RUTINA
    IF NOT ( lt_file_table IS INITIAL ).
        READ TABLE lt_file_table INTO lw_file_table INDEX 1.
        ld_o_path     = lw_file_table-filename.
        sy-subrc      = 0.
      ELSEIF ( ld_subrc GT 1 ).
        sy-subrc      = ld_subrc.
      ELSEIF ( lt_file_table IS INITIAL ).
        sy-subrc      = 0.
        ld_abend_flag = 'X'.
        ld_o_path     = ''.
      ENDIF.
  ENDCASE.
*
* ----->>> VALIDA LA EJECUCION Y RETORNA VALORES
  IF ( sy-subrc EQ 0 ) AND ( ld_o_path NE '' ).
    p_filename  = ld_o_path.
    p_rc        = 'OK'.
  ELSEIF ( ld_abend_flag EQ 'X' ) OR ( ld_o_path EQ '' ).
    p_rc        = 'CANCEL'.
  ELSE.
    p_rc        = 'ERROR'.
  ENDIF.
*
ENDFORM.                                                                                                                                                                   "
*-----------------------------------------------------------------------------------------------------------------------------------------*

Para ingresar texto en un cuadro de texto creado en la Dynpro
se debe hacer los siguiente :


*--------------------------------------------------------------------*
* Declaracion variables para el cuadro de textos
*--------------------------------------------------------------------*
*
CLASS event_handler DEFINITION.
 PUBLIC SECTION.
   METHODS: handle_f1 FOR EVENT f1 OF cl_gui_textedit
            IMPORTING sender,
            handle_f4 FOR EVENT f4 OF cl_gui_textedit
            IMPORTING sender.
ENDCLASS.
*--------------------------------------------------------------------*
DATA: init,
     container   TYPE REF TO cl_gui_custom_container,
     editor      TYPE REF TO cl_gui_textedit.
DATA: event_tab  TYPE cntl_simple_events,
     event       TYPE cntl_simple_event.
DATA handle      TYPE REF TO event_handler.
DATA: line(256)  TYPE c,
     text_tab    LIKE STANDARD TABLE OF line,
     field      LIKE line.
*--------------------------------------------------------------------*
* Declaracion de datos para el texto
*--------------------------------------------------------------------*
DATA: gt_THEADER LIKE THEAD.
DATA  BEGIN OF gt_TLINETAB OCCURS 10.
     INCLUDE STRUCTURE TLINE.
DATA: END OF gt_TLINETAB.
*--------------------------------------------------------------------*
* Implementacion de la Clase
*--------------------------------------------------------------------*
CLASS event_handler IMPLEMENTATION.
 METHOD handle_f1.
   DATA row TYPE i.
   MESSAGE i888(sabapdocu) WITH text-004.
   CALL METHOD sender->get_selection_pos
        IMPORTING from_line = row.
   CALL METHOD sender->get_line_text
        EXPORTING line_number = row
        IMPORTING text = field.
   CALL METHOD cl_gui_cfw=>set_new_ok_code   "raise PAI for
        EXPORTING new_code = 'F1'.           "system events
   CALL METHOD cl_gui_cfw=>flush.
 ENDMETHOD.
 METHOD handle_f4.
   DATA row TYPE i.
   MESSAGE i888(sabapdocu) WITH text-005.
   CALL METHOD sender->get_selection_pos
        IMPORTING from_line = row.
   CALL METHOD sender->get_line_text
        EXPORTING line_number = row
        IMPORTING text = field.
   CALL METHOD cl_gui_cfw=>flush.
 ENDMETHOD.
ENDCLASS.

*----->>> Crear custom container en la Dynpro, llamado 'CUST_TEXTO'
*----->>> En el PBO de la Dynpro crear modulo:
*---------------------------------------------------------------------*
*      Module  PBO_TEXTO  OUTPUT
*---------------------------------------------------------------------*
MODULE PBO_TEXTO OUTPUT.
 IF init is initial.
   init = 'X'.
*--------------------------------------------------------------------*
* Crear Control del Container
*--------------------------------------------------------------------*
   CREATE OBJECT: container EXPORTING container_name = 'CUST_TEXTO',
                  editor    EXPORTING parent = container,
                  handle.
*
   event-eventid = cl_gui_textedit=>event_f1.
   event-appl_event = ' '.                     
   APPEND event TO event_tab.
   event-eventid = cl_gui_textedit=>event_f4.
   event-appl_event = 'X'.                     
   APPEND event TO event_tab.
   CALL METHOD: editor->set_registered_events
                EXPORTING events = event_tab.
*--------------------------------------------------------------------*
*  Mostrar Status Bar en la Dynpro
*--------------------------------------------------------------------*
   CALL METHOD editor->set_toolbar_mode
     EXPORTING
       toolbar_mode = editor->false. 
   CALL METHOD editor->set_statusbar_mode
     EXPORTING
       statusbar_mode = editor->false.
*
   SET HANDLER handle->handle_f1
               handle->handle_f4 FOR editor.
 ENDIF.
 CALL METHOD editor->set_text_as_stream
   EXPORTING
     text = text_tab.
*
ENDMODULE.

*---->>> En el PAI de la Dynpro crear modulo:
*---------------------------------------------------------------------*
*      Module  PAI_TEXTO_REFRESH  INPUT
*---------------------------------------------------------------------*
MODULE PAI_TEXTO_REFRESH.
 CALL METHOD editor->get_text_as_stream
   IMPORTING
     text = text_tab.
ENDMODULE.

Estimado,

Si necesitase hacer algo como lo que dices...trataria de obtener los datos luego de hacer los select a las tablas...pero si fuese realmente necesario
utilizaria algo como lo siguiente codigo...

En la Tabla Interna : "TI_MATNR", quedarian todos los materiales

Ojo...este es un ejemplo rapido...y separe los rangos de los valores individuales solo como ejemplo...

REPORT  y_test_004.
*
TABLES : mara.
*
TYPES       : BEGIN OF ty_matnr,
                      matnr                        TYPE matnr,
                  END OF ty_matnr.
*
DATA        : ti_matnr                        TYPE SORTED TABLE OF ty_matnr
                                                      WITH UNIQUE KEY matnr,
                  wa_matnr                      LIKE LINE OF ti_matnr.
*
RANGES    : ra_matnr                       FOR mara-matnr.
*
DATA        : wr_matnr                       LIKE LINE OF ra_matnr.
*
*
*
SELECT-OPTIONS so_matnr FOR mara-matnr.
*
*
*
*----------------------------------------------------------------------------------------*
* OBTENER VALORES DE RANGOS : "BT"
*----------------------------------------------------------------------------------------*
LOOP AT so_matnr INTO wr_matnr.
  IF ( wr_matnr-option EQ 'BT' ).
    APPEND wr_matnr TO ra_matnr.
  ENDIF.
ENDLOOP.
*----------------------------------------------------------------------------------------*
* OBTENER MATERIALES EN RANGO
*----------------------------------------------------------------------------------------*
SELECT matnr INTO TABLE ti_matnr
  FROM mara CLIENT SPECIFIED
    WHERE mandt EQ sy-mandt
    AND   matnr IN ra_matnr.
*----------------------------------------------------------------------------------------*
* AGREGAR VALORES INDIVIDUALES DEL SELECT-OPTION A LA TABLA DE MATERIALES
*----------------------------------------------------------------------------------------*
LOOP AT so_matnr INTO wr_matnr.
  IF ( wr_matnr-option EQ 'EQ' ).
    CLEAR : wa_matnr.
    wa_matnr-matnr = wr_matnr-low.
    INSERT wa_matnr INTO TABLE ti_matnr.
  ENDIF.
ENDLOOP.

Fijate en este link...ahi esta explicado : https://danielpanaro.wordpress.com/tag/we20/

Este es un pequeño ejemplo de como leer los valores fijos asociados a un Dominio.
*

REPORT y_ebf_012 NO STANDARD PAGE HEADING.

*
DATA    : it_dd07v                TYPE STANDARD TABLE OF dd07v,
              wa_dd07v              LIKE LINE OF it_dd07v.
*
*
PARAMETERS : pa_dom             LIKE dcobjdef-name OBLIGATORY.
*
*

START-OF-SELECTION.

  REFRESH : it_dd07v.
  CLEAR    : it_dd07v.
*
  CALL FUNCTION 'DDIF_DOMA_GET'
    EXPORTING
      name          = pa_dom
      langu         = sy-langu
    TABLES
      dd07v_tab     = it_dd07v
    EXCEPTIONS
      illegal_input = 1
      OTHERS        = 2.
*
  IF ( sy-subrc EQ 0 ).
*
    IF ( sy-subrc EQ 0 ).
      LOOP AT it_dd07v INTO wa_dd07v.
*
        WRITE / : wa_dd07v-domvalue_l.
        WRITE   : wa_dd07v-ddtext.
*
      ENDLOOP.
*
    ENDIF.
*
  ENDIF.

Estimado,

-  Adicionalmente hay otro Exit es el : VSV00001 EXIT_SAPLVV01_001 Outbound: Create additional customer master segments

-  Tambien Puedes probar buscando en la SE84
    ->Ampliaciones
        ->Puntos de Ampliacion
    - En paquete coloca : "VSV" y presiona F8  ahi te saldran una lista de puntos de ampliacion que puedes investigar.
      - ES_RBDFEDEB
      - ES_RBDSEDEB
      - ES_SAPLKD01
      - ES_SAPLKD02
      - ES_SAPLVV01
      - ES_SAPLVV02
      - ES_VVSCONST

-  Lo otro que se me ocurre es buscar una BADI de la siguiente forma :
     - Ir a la transacción SE24
     - Ingresar clase CL_EXITHANDLER
     - Ingresás en el método GET_INSTANCE de esta clase y ponés un break-point en CALL METHOD cl_exithandler=>get_class_name_by_interface.

     - Ahora ejecutás tu transacción normalmente y te fijás si frena en el momento deseado. Va a frenar en muchos lugares porque va a frenar en todas
       las BADI's por las que pases, por lo que te recomiendo que pongas el break justo en el momento en que deseás ver si existe una BADI.
       En la variable EXIT_NAME vas a encotrar el nombre de la BADI.


-  Por ultimo recuerda que para leer ese campo que dices de largo 1000 se hace mas o menos de la siguiente forma :

       DATA : kna1m   TYPE e1kna1m.
       LOOP AT IDOC_DATA.
         CASE idoc_data-segnam.
           WHEN 'E1KNA1M'.
             kna1m = idoc_data-sdata.
*
*             AQUI TU CODIGO
*
         ENDCASE.                             
       ENDLOOP.

Ojala esto te ayude en algo.