Foro de programación ABAP

Excelente...Felicitaciones.

Carlos,

Los IDOCs en si son una estructura desarrollada para el intercambio de informacion entre sistemas SAP o bien la comunicación del SAP con sistemas externos (EDI - ALE), se utilizan principalmente para carga y actualizacion de datos en SAP...La estructura de los IDOCs tambien puede ser ampliada (como las tablas SAP con estructuras APPEND) o bien puedes crear tus propios IDOCs.

La Estructuras del IDOC esta formada por Registros de control, Registros de Datos y Registros de Estado :

- Registro de control:
     Contiene toda la información administrativa del IDOC, como el sistema origen y el de destino, el tipo de IDOC del que se trata.
     Este registro es de vital importancia ya que a partir de él se permitirá saber quien va a ser el destinatario del IDOC.
     La estructura de este segmento de control es igual para todos los IDOCs. Cada IDOC contiene uno y sólo un registro de control.

- Registro de datos:
     En el registro de datos esta toda la información enviada/recibida.
     El registro de datos va a estar dividido en distintos segmentos en los cuáles van a estar almacenados los datos. Estos segmentos a su vez pueden
     contener otros segmentos. Cada IDOC podrá tener dentro de los registros de datos “N” segmentos donde se almacenan los datos.

- Registro de estado:
     Es el historial del procesamiento del IDOC en las distintas etapas.
     Cada IDOC tendrá “N” registros de estado.

 · Generación del IDOC
        La generación del IDOC se puede dar por medio de mensajes asignados a los procesos – Mensaje con procesamiento EDI – o bien directamente         
        desde aplicación - Programas ABAP / BAPIs, punteros de modificaciones, programas generación de IDOCs, procesos empresariales ALE;
        El IDOC generado es almacenado en la base de datos SAP a espera de su envío;
· Envío del IDOC a la puerta de salida SAP
        Mediante el programa específico de procesamiento, el sistema hace la lectura del IDOC generado y se lo envía a su puerta de salida.
        Se determina el interlocutor destinatario que tiene asignado la puerta de salida SAP y se actualiza el status de procesamiento del IDOC.
· Interfase SAP/Sistema destino
        Al procesar el IDOC para salida se envía la información al sistema destino por asignado a la puerta de comunicación del SAP

Sobre la configuracion de IDOCs...puertos, ampliacion...etc, son parte del trabajo nuestro (desarrollador), no de los BASIS.

Los IDOCs mas utilizados son los siguientes :
    - Datos Maestros: Clientes - DEBMAS03
    - Datos Maestros: Proveedores - CREMAS05
    - Datos Maestros: Materiales - MATMAS05
    - Pedidos de ventas - ORDERS05
    - Datos de Entregas - DELVRY05
    - Facturas de ventas - INVOIC02
    - Facturas de compras - INVOIC01

Algunas transacciones utilizadas para los IDOCs son :
   - WE19    : (Ingresar datos y reprocesar Idocs para testeo - visible/debugging)
   - WE21     : Puertas IDoc
   - WE20    : Interlocutores EDI
   - WE02    : Listado IDoc con status
   - WE05    : (Listar Idocs )
   - WE60    : Mensajes IDoc
   - WE16    : Cargar fichero de texto IDoc
   - BD87    : Reprocesado de IDoc

Espero esto aclare un poco tus dudas...Si necesitas algo mas especifico avisame por correo.

Saludos.

Estimado, para poder ayudarte necesito me detalles mas lo que te piden..
Lo que tienes hasta el momento aunque no es lo optimo es la base de lo que necesitas...el repetir la declaracion de tablas internas y juntar los datos en una
tabla de salida o mediante LOOP's filtrar lo que quieres y mostrar el resultado...todo depende de lo que realmente necesites.

Saludos

Estimado...la funcion en donde esta el User-Exit es la siguiente y como podras notar viene la estructura I_EKKO ... solo tienes que rescatar de alli el
ebeln .... I_EKKO-EBELN.


function exit_sapmm06e_004.
*"----------------------------------------------------------------------
*"*"Lokale Schnittstelle:
*"  IMPORTING
*"     VALUE(I_T001) LIKE  T001 STRUCTURE  T001
*"     VALUE(I_EKKO) LIKE  EKKO STRUCTURE  EKKO
*"     VALUE(I_LFA1) LIKE  LFA1 STRUCTURE  LFA1
*"  CHANGING
*"     VALUE(IMPORT)
*"     VALUE(XEGIMP)
*"     VALUE(EGIMP)
*"----------------------------------------------------------------------


  include zxm06u24.


endfunction.

Estimado...te cuento como lo he hecho y no tengo problemas...por ejemplo tengo
una Dynpro principal del tipo normal y los TAB son Subscreen que son siete.

Si te fijas no he identificado ningun campo en la logica de proceso de las Dynpro...lo
que si estan definidos y declarados como estructuras en el TOP...una estructura para
cada Dynpro. con todos sus campos.

Otra forma es que en la logica del PAI... despues del USER_COMMAND...actualices valores sin necesidad de dar un ENTER...para esto tienes que utilizar la funcion "DYNP_VALUES_UPDATE".

Cualquier cosa avisame

Ojala esto te ayude...


La Dynpro principal es la : 3000
*
*----------------------------------------------------------------------*
* PBO
*----------------------------------------------------------------------*
*
PROCESS BEFORE OUTPUT.
*
  MODULE status_3000.                        " Aqui actualizo atributos de los campos de la dynpro
*
  MODULE t_ctrl_active_tab_set.                  " Aqui controlo en que TAB estoy
*
  CALL SUBSCREEN:
       3001_sca INCLUDING g_t_ctrl-prog '3001',
       3002_sca INCLUDING g_t_ctrl-prog '3002',
       3003_sca INCLUDING g_t_ctrl-prog '3003',
       3004_sca INCLUDING g_t_ctrl-prog '3004',
       3005_sca INCLUDING g_t_ctrl-prog '3005',
       3006_sca INCLUDING g_t_ctrl-prog '3006',
       3007_sca INCLUDING g_t_ctrl-prog '3007'.
*
*
*----------------------------------------------------------------------*
* PAI
*----------------------------------------------------------------------*
*
PROCESS AFTER INPUT.
*
  CALL SUBSCREEN:
         3001_sca,
         3002_sca,
         3003_sca,
         3004_sca,
         3005_sca,
         3006_sca,
         3007_sca.


  FIELD wa_dato_xx MODULE get_datos_generales_pai ON REQUEST.              " Aqui traigo y asigno valores de campos a la dynpro
*
  MODULE user_command_3000.                               " Aqui controlas botones y modifica valores...etc.






La Subscreen : 3001 ( primer TAB )
*
*----------------------------------------------------------------------*
* PBO
*----------------------------------------------------------------------*
*
PROCESS BEFORE OUTPUT.
*
  MODULE atrib_dynpro_3001.                              " Aqui modifico atributos de los campos en la pantalla
*
  MODULE act_data_dynpro_3001.                           " Aqui valido posibles modificaciones, traigo textos, etc.
*

*
*----------------------------------------------------------------------*
* PAI
*----------------------------------------------------------------------*
*
PROCESS AFTER INPUT.
*
*
  FIELD wa_dato_001           MODULE valida_dato_001.           " Validaciones especificas a un campo

*
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
*
  MODULE user_command_3001.                    " Aqui controlas botones y modifica valores de campos de la Subscreen etc.
*
*

Aqui les dejo un pequeño ejemplo de como modificar datos de direccion...


REPORT y_test_050.

TYPE-POOLS: szadr.

*
*----------------------------------------------------------------------*
* DECLARACION DE VARIABLES
*----------------------------------------------------------------------*
*
DATA : ld_addnr             TYPE ad_addrnum.

*
*----------------------------------------------------------------------*
* DECLARACION DE TABLAS INTERNAS Y ESTRUCTURAS
*----------------------------------------------------------------------*
*

DATA : wx_kna1              TYPE kna1.                                "
DATA : addr_complete        TYPE szadr_addr1_complete.
DATA : adsmtp_line          TYPE szadr_adsmtp_line,
       addr1_line           TYPE szadr_addr1_line,
       adtel_line           TYPE szadr_adtel_line.

DATA : ld_recode            LIKE  szad_field-returncode.
DATA : lt_error             TYPE STANDARD TABLE OF addr_error.

* ----------------------------------------------------------------*
* EJECUTAR BAPI : ADDR_GET_COMPLETE
* ----------------------------------------------------------------*

*
*  Aqui codigo para obtener en WX_KNA1 en Numero de Direccion "ADRNR"
*



*

addr_complete-addrnumber = wx_kna1-adrnr.

*
*  Obtener Datos de Direccion Completos
*
CALL FUNCTION 'ADDR_GET_COMPLETE'
  EXPORTING
    addrnumber        = addr_complete-addrnumber
    addrhandle        = addr_complete-addrhandle
  IMPORTING
    addr1_complete    = addr_complete
  EXCEPTIONS
    parameter_error   = 1
    address_not_exist = 2
    internal_error    = 4
    OTHERS            = 5.

*
*  Aqui codigo de lo que se quiera modificar...
*



*
* Ejemplo : Para Modificar Datos de : addr1_line
*
READ TABLE addr_complete-addr1_tab INTO addr1_line INDEX 1 .
addr1_line-data-extension2  = 'TEST 01'.
addr1_line-data-house_num1  = '1232'.

MODIFY addr_complete-addr1_tab FROM addr1_line
                               INDEX 1.


*
* Ejemplo : Para Modificar el Telefono 01
*

CLEAR : adtel_line-adtel.
adtel_line-adtel-country      = 'CL'.                                    " Pais
adtel_line-adtel-tel_number   = '666222666'.                             " Telefono Fijo - 01
adtel_line-adtel-telnr_long   = '666222666'.                             " Telefono Fijo - 01
adtel_line-adtel-telnr_call   = '666222666'.                             " Telefono Fijo - 01
adtel_line-adtel-home_flag    = 'X'.                                     " Dirección destinatario en esta cl.comunicación (vínc.correo)
adtel_line-adtel-r3_user      = '1'.                                     " Tipo de Telefono
adtel_line-adtel-updateflag   = 'I'.
APPEND adtel_line TO addr_complete-adtel_tab.

*
* ----------------------------------------------------------------*
* EJECUTAR BAPI : ADDR_MAINTAIN_COMPLETE
* ----------------------------------------------------------------*

CALL FUNCTION 'ADDR_MAINTAIN_COMPLETE'
  EXPORTING
    updateflag               = 'U'
    addr1_complete           = addr_complete
    address_group            = 'BP'
    substitute_all_comm_data = ' '
    check_address            = ' '
  IMPORTING
    returncode               = ld_recode
  TABLES
    error_table              = lt_error
  EXCEPTIONS
    parameter_error          = 1
    address_not_exist        = 2
    handle_exist             = 4
    internal_error           = 5
    OTHERS                   = 6.
*
IF ( sy-subrc EQ 0 ).

  CALL FUNCTION 'ADDR_MEMORY_SAVE'
    EXPORTING
      execute_in_update_task = 'X'
    EXCEPTIONS
      address_number_missing = 1
      person_number_missing  = 2
      internal_error         = 3
      database_error         = 4
      reference_missing      = 5
      OTHERS                 = 6.

*
  CALL FUNCTION 'BAPI_TRANSACTION_COMMIT'
    EXPORTING
      wait = 'X'.

*
ENDIF.

La de idea de esta rutina es no tener que estar asignando variables, estructuras o comparando siempre línea a línea...
Esta idea llego cuando estaba desarrollando una aplicación que debe maneja bastantes datos en memoria, poder modificar
datos y luego reversar los datos, asignar valores a variables desde una pantalla a varios campos de distintas áreas de trabajo...
entonces pensé...si SAP maneja el concepto de áreas de trabajo...porque no aplicar esto a mi programa...entonces pensé en crear una
tabla interna con correlativos de áreas o procesos y los campos de estructuras o variables que deseo estar asignando de un lado a otro y
como resultado salió este programita...Ojala les sirva ...El código fuente da para mucho mas...

Cualquier idea o aporte...será bien recibido



REPORT y_proceso_dinamico.


*-----------------------------------------------------------------------------------------------------------------*
* Tabla para Catalogo de Campos de TBI's y Variables
* Para Utilizar Field-Symbols en Asignacion Dinamica
* De Datos desde un Lado a Otro...
*-----------------------------------------------------------------------------------------------------------------*
TYPES : BEGIN OF ty_itab,
          proceso(5)          TYPE n,                     " Correlativo Identifica Datos a Procesar
          tabla01             TYPE tabname,               " Area de Trabajo 01
          campo01             TYPE fieldname,             " Campo / Variable Area de Trabajo 01
          tabla02             TYPE tabname,               " Area de Trabajo 01
          campo02             TYPE fieldname,             " Campo / Variable Area de Trabajo 01
        END OF ty_itab.

DATA  : ti_itab               TYPE STANDARD TABLE OF ty_itab,
        wa_itab               TYPE ty_itab.
*-----------------------------------------------------------------------------------------------------------------*
DATA : gd_telefono_01(15)     TYPE c,
       gd_telefono_02(15)     TYPE c.
*-----------------------------------------------------------------------------------------------------------------*
DATA : lx_kna1                TYPE kna1.
*-----------------------------------------------------------------------------------------------------------------*
DATA : gd_retorno(1)          TYPE c.
*-----------------------------------------------------------------------------------------------------------------*
DATA : BEGIN OF wa_area_001,
         name1                LIKE lx_kna1-name1,
         ort01                LIKE lx_kna1-ort01,
         regio                LIKE lx_kna1-regio,
         name3                LIKE lx_kna1-name3,
         fono_01(20)          TYPE c,
         fono_02(20)          TYPE c,
         fecha                TYPE datum,
         hora                 TYPE uzeit,
       END OF wa_area_001.

DATA : gd_usuario(15)         TYPE c.
*
*-----------------------------------------------------------------------------------------------------------------*
* MACRO : MC_ADD_TO_ITAB : Agrega definiciones de asignacion o comparacion
*-----------------------------------------------------------------------------------------------------------------*
*
DEFINE mc_add_to_itab.
*
  clear : wa_itab.
  wa_itab-proceso   = &1.
  wa_itab-tabla01   = &2.
  wa_itab-campo01   = &3.
  wa_itab-tabla02   = &4.
  wa_itab-campo02   = &5.
  append wa_itab to ti_itab.
*
END-OF-DEFINITION.
*
*-----------------------------------------------------------------------------------------------------------------*
* START-OF-SELECTION
*-----------------------------------------------------------------------------------------------------------------*
*
START-OF-SELECTION.
*
  PERFORM llena_tbi_diccionario.
*-----------------------------------------------------------------------------------------------------------------*
*  llenado de las tablas internas o variables
*  Aqui el Codigo...de Ejemplo.  AREA 01
*-----------------------------------------------------------------------------------------------------------------*
  wa_area_001-name1       = 'JUAN PEREZ GONZALEZ'.
  wa_area_001-ort01       = 'CUALQUIER COSA'.
  wa_area_001-regio       = '13'.
  wa_area_001-name3       = 'NOMBRE TRES'.
  wa_area_001-fono_01     = '(56 2) 6771474'.
  wa_area_001-fono_02     = '(56 9) 9234532'.

  gd_usuario              = 'XXXX'.

  BREAK-POINT.
* REVISAR ESTADO DE WA_AREA_001 Y LX_KNA1 Y LA VARIABLE GD_USUARIO

*-----------------------------------------------------------------------------------------------------------------*
*  Mover de Izquierda a Derecha.
  PERFORM frm_proceso_dinamico USING 'DE_01_A_02'
                                     '00001'
                                CHANGING gd_retorno.
  BREAK-POINT.
* GD_RETORNO = 'T' --> OK
* GD_RETORNO = 'F' --> ERROR
*
* REVISAR ESTADO DE WA_AREA_001 Y LX_KNA1 Y LA VARIABLE GD_USUARIO



*-----------------------------------------------------------------------------------------------------------------*
*  llenado de las tablas internas o variables
*  Aqui el Codigo...de Ejemplo.  AREA 02
*-----------------------------------------------------------------------------------------------------------------*
  lx_kna1-name1           = 'JOSE LX_KNA1'.
  gd_telefono_01          = '(56 2) LX_KNA1'.
  gd_telefono_02          = '(56 9) LX_KNA1'.
*-----------------------------------------------------------------------------------------------------------------*
*  Mover de Derecha a Izquierda.

  PERFORM frm_proceso_dinamico USING 'DE_02_A_01'
                                     '00001'
                                CHANGING gd_retorno.
  BREAK-POINT.
* GD_RETORNO = 'T' --> OK
* GD_RETORNO = 'F' --> ERROR
*
* REVISAR ESTADO DE WA_AREA_001 Y LX_KNA1 Y LA VARIABLE GD_USUARIO

*-----------------------------------------------------------------------------------------------------------------*
*  Validar si contenido de los campos son iguales.
  PERFORM frm_proceso_dinamico USING '01_EQ_02'
                                     '00001'
                                CHANGING gd_retorno.
  BREAK-POINT.
* GD_RETORNO = 'T' --> OK
* GD_RETORNO = 'F' --> ERROR
*
* REVISAR ESTADO DE WA_AREA_001 Y LX_KNA1 Y LA VARIABLE GD_USUARIO

*-----------------------------------------------------------------------------------------------------------------*
*  Mover de Izquierda a Derecha.
  PERFORM frm_proceso_dinamico USING 'DE_01_A_02'
                                     '00001'
                                CHANGING gd_retorno.

  BREAK-POINT.
* GD_RETORNO = 'T' --> OK
* GD_RETORNO = 'F' --> ERROR
*
* REVISAR ESTADO DE WA_AREA_001 Y LX_KNA1 Y LA VARIABLE GD_USUARIO
*

*
END-OF-SELECTION.
*
*-----------------------------------------------------------------------------------------------------------------*
*  Aqui es donde vamos agregando las estrcuras, tablas o variables que deaseamos
*  asignar o comparar en un determinado momento
*-----------------------------------------------------------------------------------------------------------------*
*
FORM llena_tbi_diccionario.

  REFRESH : ti_itab.
  CLEAR   : ti_itab, wa_itab.

  mc_add_to_itab    '00001'   'WA_AREA_001'   'NAME1'                 'LX_KNA1'      'NAME1'.
  mc_add_to_itab    '00001'   'WA_AREA_001'   'ORT01'                 'LX_KNA1'      'ORT01'.
  mc_add_to_itab    '00001'   'WA_AREA_001'   'REGIO'                 'LX_KNA1'      'REGIO'.
  mc_add_to_itab    '00001'   'WA_AREA_001'   'NAME3'                 'LX_KNA1'      'NAME3'.
  mc_add_to_itab    '00001'   'WA_AREA_001'   'FONO_01'               ''             'GD_TELEFONO_01'.
  mc_add_to_itab    '00001'   'WA_AREA_001'   'FONO_02'               ''             'GD_TELEFONO_02'.
  mc_add_to_itab    '00001'   'WA_AREA_001'   'FECHA'                 ''             'SY-DATUM'.
  mc_add_to_itab    '00001'   'WA_AREA_001'   'HORA'                  ''             'SY-UZEIT'.
  mc_add_to_itab    '00001'   ''              'GD_USUARIO'            ''             'SY-UNAME'.

ENDFORM.                                                                                                          "
*
*-----------------------------------------------------------------------------------------------------------------*
* FORM : FRM_PROCESO_DINAMICO : Realiza Asignaciones o Comparaciones se excluyen
*                                                          las asignacines a variables de sistema "SY-*"
*-----------------------------------------------------------------------------------------------------------------*
*
FORM frm_proceso_dinamico  USING    p_ld_sentido
                                    p_ld_proceso
                           CHANGING p_gd_retorno.
*
  DATA : ld_tbicamp1(40)  TYPE c,
         ld_tbicamp2(40)  TYPE c.
  DATA : ld_var_aux1(100) TYPE c,
         ld_var_aux2(100) TYPE c.

  FIELD-SYMBOLS : <fs_scr>, <fs_tbi>.
  FIELD-SYMBOLS : <fs_ax1>, <fs_ax2>.

  p_gd_retorno = 'T'.
*

  LOOP AT ti_itab INTO wa_itab WHERE proceso EQ p_ld_proceso.
    CLEAR : ld_tbicamp1, ld_tbicamp2.
*
    IF ( wa_itab-tabla01 NE '' ).
      CONCATENATE wa_itab-tabla01 '-' wa_itab-campo01 INTO ld_tbicamp1.
    ELSE.
      MOVE wa_itab-campo01 TO ld_tbicamp1.
    ENDIF.
*
    IF ( wa_itab-tabla02 NE '' ).
      CONCATENATE wa_itab-tabla02 '-' wa_itab-campo02 INTO ld_tbicamp2.
    ELSE.
      MOVE wa_itab-campo02 TO ld_tbicamp2.
    ENDIF.

    ASSIGN (ld_tbicamp1) TO <fs_scr>.
    ASSIGN (ld_tbicamp2) TO <fs_tbi>.

    CASE p_ld_sentido.

      WHEN 'DE_01_A_02'.
*
        IF ( wa_itab-campo02+00(03) NE 'SY-' ).
          IF ( wa_itab-tabla01 EQ '' ) AND ( wa_itab-tabla02 EQ '' ).
            ASSIGN (ld_tbicamp2) TO <fs_ax2>.
            <fs_tbi> = <fs_scr>.
          ELSE.
            <fs_tbi> = <fs_scr>.
          ENDIF.
        ENDIF.


*
      WHEN 'DE_02_A_01'.
*
        IF ( wa_itab-campo01+00(03) NE 'SY-' ).

          IF ( wa_itab-tabla01 EQ '' ) AND ( wa_itab-tabla02 EQ '' ).
            ASSIGN (ld_tbicamp2) TO <fs_ax2>.
            <fs_scr> =  <fs_ax2>.
          ELSE.
            <fs_scr> = <fs_tbi>.
          ENDIF.
        ENDIF.
*
      WHEN '01_EQ_02'.

        IF ( <fs_tbi> NE <fs_scr> ).
          p_gd_retorno = 'F'.
          EXIT.
        ENDIF.

    ENDCASE.

*
  ENDLOOP.
*
ENDFORM.                                                                                                          "
*