Texto - Datos Basicos del Material

[abapito]

Hola, como puedo sacar el texto que se encuentra en la transacción MM02, en Datos Adicionales y la pestaña ¿Texto Datos Básicos?


Gracias...

[dluis]

Puedes utilizar la función READ_TEXT_INLINE, te agrego un ejemplo.

Código:

  TYPES: it_lin LIKE  tline.

  DATA: it_lines TYPE TABLE OF it_lin,
        it_inline TYPE TABLE OF it_lin,
        line TYPE it_lin.
  DATA: lf_matnr     LIKE mara-matnr,
        lf_matnr_tmp LIKE  thead-tdname.


  CALL FUNCTION 'CONVERSION_EXIT_ALPHA_INPUT'
    EXPORTING
      input  = i_datos-matnr
    IMPORTING
      output = lf_matnr.

  MOVE lf_matnr TO lf_matnr_tmp.
  IF p_langu IS INITIAL.
    p_langu = 'S'.
  ENDIF.

  CALL FUNCTION 'READ_TEXT_INLINE'
    EXPORTING
      id              = 'GRUN'
      inline_count    = 1
      language        = p_langu
      name            = lf_matnr_tmp
      object          = 'MATERIAL'
    TABLES
      inlines         = it_inline
      lines           = it_lines
    EXCEPTIONS
      id              = 1
      language        = 2
      name            = 3
      not_found       = 4
      object          = 5
      reference_check = 6
      OTHERS          = 7.

  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

* READ TABLE it_lines INTO line INDEX 1.

  LOOP AT it_lines INTO line.
    CONCATENATE i_datos-txt_datos_basicos line-tdline
           INTO i_datos-txt_datos_basicos SEPARATED BY space.
  ENDLOOP.